ティラノビルダー・スクリプト で
スキップボタン付きのスタッフロールを作る方法。
スタッフロールをスクリプトで記述する方法は
こちらのティラノスクリプトwiki様を見ると実装することができるのですが。
この方法だと、スキップボタンを実装することができません。
スタッフロールの文字がアニメーションするアニメーション待ちに
[wa]タグが使われているからです。
[wa]はアニメーションが終わるまで、次の処理に進まないタグです。
なのでこれを使わないで[wait time=" "]を使い、
ロール終了後に
[cm]（改ページ）
[s]（ゲーム停止）
を入れます。
一定時間経過すると選択肢が消えてしまう
早押しクイズの仕組みみたいなの使ってスタッフロールを流しながら、
スキップボタンを機能させます。
以下、スクリプトです。＋＋＋＋＋＋＋＋＋＋＋＋＋＋;エンディングテスト
[cm]
;背景変更
[bg storage="0_kuro.png" time="100"]
;メニューボタンの非表示
@hidemenubutton
;スキップボタン
[glink name="sukip" color="btn_05_black" size="18" width="200" x="800" y="5" text="skip" storage="" target="*skip" ]
@anim name="sukip" time=10 opacity=150
;スタッフロール
@layopt layer=0 visible=false
[ptext layer=0 text="クレジット" size=20 x=400 y=300 color=snow name="text"]
[ptext layer=0 text="スタッフロール" size=20 x=400 y=400 color=snow name="text"]
[ptext layer=0 text="スタッフロール" size=20 x=400 y=500 color=snow name="text"]
[ptext layer=0 text="スタッフロール" size=20 x=400 y=600 color=snow name="text"]
[ptext layer=0 text="スタッフロール" size=20 x=400 y=700 color=snow name="text"]
[ptext layer=0 text="スタッフロール" size=20 x=400 y=800 color=snow name="text"]
[ptext layer=0 text="スタッフロール" size=20 x=400 y=900 color=snow name="text"]
[wait time=1]
;スタッフロールの文字がアニメーションする設定
[keyframe name="animation1"]
[frame p=0% y="400"]
[frame p=100% y="-1000"]
[endkeyframe]
;アニメーションの実行 3秒かけてキーフレームアニメーションを実行
[kanim name="text" keyframe="animation1" time="30000" easing="linear" ]
;スタッフロールを描写したレイヤーが見えるように
@layopt layer=0 visible=true
;アニメーションの再生を待つ（waを使うとボタンが使えないためウェイト）
[wait time="30000"]
[cm]
;エンドテキスト
[ptext text="The End" layer="0" x="580" y="250" size="35" edge="0xffffff" color="0xffffff" name="end" time="2000" name=end]
;クリッカブルでクリックでｓ(ゲーム停止)を飛ばす
[clickable width="1100" height="760" target="*skip" ]
;ゲーム停止
[s]
;クレジット終了
*skip
[cm]
[wait_cancel]
;テキストを消去
[freelayer layer="0"]
;タイトルへジャンプ
*title
@bg storage ="title.jpg" time=2000
@jump storage="title.ks" target="start"
＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋
このスタッフロールの後ろで背景画像を変更したいけど
うまくいかないということをお聞きしたので
検証しました。
→
スキップボタン付きスタッフロール、画像変更もしたいティラノスクリプトでスキップボタン＋スタッフロール＋背景変更です。
