俺式メッセージウィンドウ変更方法。ティラノスクリプト
すごくまえーにも書いたんだけどティラノビルダーv17xとかだった気がするので
最近やってる方法（現在はティラノスタジオv60xで制作）書いときます。
マクロでメッセージウィンドウ変える記述です。
まず、読み込み用ファイルを作ります。
（ティラノビルダーだとscenario\system の中にmessage_window.ksがあって
そこに記述あります。）
↑このファイルはビルダーでUI設定いじるとオートで更新されるので
ビルダー更新すると直されますので加筆するときは注意
ティラノスタジオはないので自分で作ります。
yomiomi_gamemei.ksとかわかりやすい名のKSファイルで
;メッセージウィンドウの設定
[position layer="message0" frame="mesew.png" left="0" width="1280" height="270" top="450" opacity="255" page=fore visible=false ]
;文字が表示される領域を調整
[position layer=message0 page=fore margint="110" marginl="200" marginr="210" marginb="20" width="1280" align="center"]
;キャラクターの名前が表示される文字領域
[ptext name="chara_name_area" layer="message0" color=0xf0e68c size=32 x=10 y=520 bold="false" edge="0x333333" shadow="0x555555" width="1240" align="center"]
;上記で定義した領域がキャラクターの名前表示であることを宣言（これがないと#の部分でエラーになります）
[chara_config ptext="chara_name_area"]
;クリック待ちグリフ位置変更
[glyph fix="true" left="1210" top="650"]
;メニューボタン出すマクロ
[macro name="menu_show"]
;ボタンの背景影
[image storage="botankage.png" layer="0" visible="true" name="kage" folder="image" time="100" zindex="10"]
[button graphic="button/skip.png" enterimg="button/skip2.png" clickimg="button/skip2.png" name="skip" x="61" y="1" fix="true " role="skip" clickse="katya.mp3" ]
[button graphic="button/auto.png" enterimg="button/auto2.png" clickimg="button/auto2.png" name="auto" x="1" y="1" fix="true " role="auto" clickse="katya.mp3" ]
[button graphic="button/log.png" enterimg="button/log2.png" clickimg="button/log2.png" name="backlog" x="121" y="1" fix="true " role="backlog" clickse="katya.mp3" ]
[button graphic="button/menu.png" enterimg="button/menu2.png" clickimg="button/menu2.png" name="menu" x="1220" y="1" fix="true " role="menu" clickse="katen.mp3" ]
[endmacro]
;メニューボタン消すマクロ
[macro name="menu_hide"]
[clearfix]
;影消す
[free name="kage" layer="0" time="300"]
[endmacro]
;メッセージウィンドウ出すマクロ
[macro name="show_mesew"]
[anim layer="message0" time="200" opacity="255"]
[wait time="200"]
[layopt layer="message0" visible="true" ]
[resetfont ]
[endmacro]
※↑灰色の文字のところはビルダーだとあるからいれない
;メッセージウィンドウかえるマクロ中央黒
[macro name="show_mesew_k"]
[position layer="message0" frame="mesew_k.png" width="1280" height="270" top="450" left="0" opacity="255" margint="110" marginl="180" marginr="210" marginb="20" page=fore visible="true" ]
[anim layer="message0" time="200" opacity="255"]
[wait time="200"]
[layopt layer="message0" visible="true" ]
[font color="0xcccccc" ]
[endmacro]
;メッセージウィンドウかえるマクロ全面背景無し
[macro name="mesew_e"]
[position layer="message0" frame="mesew_e.png" width="1280" height="720" top="0" left="0" opacity="100" marginl="140" margint="180" marginr="140" marginb="300" page=fore visible="true" ]
[anim layer="message0" time="200" opacity="255"]
[wait time="200"]
[layopt layer="message0" visible="true" ]
[endmacro]
;メッセージウィンドウ中央にもどすマクロ
[macro name="show_mesew_def"]
[position layer="message0" frame="mesew.png" left="0" width="1280" height="270" top="450" opacity="255" margint="110" marginl="180" marginr="210" marginb="20" page=fore visible="true" ]
[resetfont ]
[endmacro]
;メッセージウィンドウ消すマクロ
[macro name="hide_mesew"]
[anim layer="message0" time="200" opacity="0"]
[wait time="200"]
[layopt layer="message0" visible="false" ]
[endmacro]
[return]
＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊
オレンジ文字のところがマクロの設定です。
これを読み込んでおいて
[mesew_k]と居れるとメッセージウィンドウ全面で黒いやつとかに変えられます。
また変えたいときは[show_mesew_def]となります。
読み込みはfist.ksに
@call storage="yomikomi_lucky.ks"
といれたりしていますが、ビルダーだとfist.ks自動で更新されちゃうからそこだけ注意やな
マクロ使う前に絶対とおるところで読み込んどくと便利（タイトルksとかかな？）
ティラノスタジオに移行してからは
キャラの表示設定とかもぜんぶ読み込みファイルに記述して読み込んでる。
こういうやつ↓ずらーっと
（ビルダーだとキャラ登録するとオートでファイル作ってしてくれてる
（ビルダーだとキャラ登録するとオートでファイル作ってしてくれてる
;このゲームで登場するキャラクターを宣言
;ジェイル
[chara_new name="jail" storage="chara/jail/jail.png" jname="ジェイル"]
;キャラクターの表情登録
[chara_face name="jail" face="defo" storage="chara/jail/jail.png"]
[macro name="show_mesew_def"]
この間は自分で設定
[endmacro]
マクロの作り方でした。
この間は自分で設定
[endmacro]
マクロの作り方でした。
PR